You can not select more than 25 topics Topics must start with a letter or number, can include dashes ('-') and can be up to 35 characters long.
 
 
 
 
 
 

123 lines
4.9 KiB

  1. # ===========================================================================
  2. # https://www.gnu.org/software/autoconf-archive/ax_cflags_warn_all.html
  3. # ===========================================================================
  4. #
  5. # SYNOPSIS
  6. #
  7. # AX_CFLAGS_WARN_ALL [(shellvar [,default, [A/NA]])]
  8. # AX_CXXFLAGS_WARN_ALL [(shellvar [,default, [A/NA]])]
  9. # AX_FCFLAGS_WARN_ALL [(shellvar [,default, [A/NA]])]
  10. #
  11. # DESCRIPTION
  12. #
  13. # Try to find a compiler option that enables most reasonable warnings.
  14. #
  15. # For the GNU compiler it will be -Wall (and -ansi -pedantic) The result
  16. # is added to the shellvar being CFLAGS, CXXFLAGS, or FCFLAGS by default.
  17. #
  18. # Currently this macro knows about the GCC, Solaris, Digital Unix, AIX,
  19. # HP-UX, IRIX, NEC SX-5 (Super-UX 10), Cray J90 (Unicos 10.0.0.8), and
  20. # Intel compilers. For a given compiler, the Fortran flags are much more
  21. # experimental than their C equivalents.
  22. #
  23. # - $1 shell-variable-to-add-to : CFLAGS, CXXFLAGS, or FCFLAGS
  24. # - $2 add-value-if-not-found : nothing
  25. # - $3 action-if-found : add value to shellvariable
  26. # - $4 action-if-not-found : nothing
  27. #
  28. # NOTE: These macros depend on AX_APPEND_FLAG.
  29. #
  30. # LICENSE
  31. #
  32. # Copyright (c) 2008 Guido U. Draheim <guidod@gmx.de>
  33. # Copyright (c) 2010 Rhys Ulerich <rhys.ulerich@gmail.com>
  34. #
  35. # This program is free software; you can redistribute it and/or modify it
  36. # under the terms of the GNU General Public License as published by the
  37. # Free Software Foundation; either version 3 of the License, or (at your
  38. # option) any later version.
  39. #
  40. # This program is distributed in the hope that it will be useful, but
  41. # WITHOUT ANY WARRANTY; without even the implied warranty of
  42. # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU General
  43. # Public License for more details.
  44. #
  45. # You should have received a copy of the GNU General Public License along
  46. # with this program. If not, see <https://www.gnu.org/licenses/>.
  47. #
  48. # As a special exception, the respective Autoconf Macro's copyright owner
  49. # gives unlimited permission to copy, distribute and modify the configure
  50. # scripts that are the output of Autoconf when processing the Macro. You
  51. # need not follow the terms of the GNU General Public License when using
  52. # or distributing such scripts, even though portions of the text of the
  53. # Macro appear in them. The GNU General Public License (GPL) does govern
  54. # all other use of the material that constitutes the Autoconf Macro.
  55. #
  56. # This special exception to the GPL applies to versions of the Autoconf
  57. # Macro released by the Autoconf Archive. When you make and distribute a
  58. # modified version of the Autoconf Macro, you may extend this special
  59. # exception to the GPL to apply to your modified version as well.
  60. #serial 16
  61. AC_DEFUN([AX_FLAGS_WARN_ALL],[dnl
  62. AS_VAR_PUSHDEF([FLAGS],[_AC_LANG_PREFIX[]FLAGS])dnl
  63. AS_VAR_PUSHDEF([VAR],[ac_cv_[]_AC_LANG_ABBREV[]flags_warn_all])dnl
  64. AC_CACHE_CHECK([m4_ifval($1,$1,FLAGS) for maximum warnings],
  65. VAR,[VAR="no, unknown"
  66. ac_save_[]FLAGS="$[]FLAGS"
  67. for ac_arg dnl
  68. in "-warn all % -warn all" dnl Intel
  69. "-pedantic % -Wall" dnl GCC
  70. "-xstrconst % -v" dnl Solaris C
  71. "-std1 % -verbose -w0 -warnprotos" dnl Digital Unix
  72. "-qlanglvl=ansi % -qsrcmsg -qinfo=all:noppt:noppc:noobs:nocnd" dnl AIX
  73. "-ansi -ansiE % -fullwarn" dnl IRIX
  74. "+ESlit % +w1" dnl HP-UX C
  75. "-Xc % -pvctl[,]fullmsg" dnl NEC SX-5 (Super-UX 10)
  76. "-h conform % -h msglevel 2" dnl Cray C (Unicos)
  77. #
  78. do FLAGS="$ac_save_[]FLAGS "`echo $ac_arg | sed -e 's,%%.*,,' -e 's,%,,'`
  79. AC_COMPILE_IFELSE([AC_LANG_PROGRAM],
  80. [VAR=`echo $ac_arg | sed -e 's,.*% *,,'` ; break])
  81. done
  82. FLAGS="$ac_save_[]FLAGS"
  83. ])
  84. AS_VAR_POPDEF([FLAGS])dnl
  85. AX_REQUIRE_DEFINED([AX_APPEND_FLAG])
  86. case ".$VAR" in
  87. .ok|.ok,*) m4_ifvaln($3,$3) ;;
  88. .|.no|.no,*) m4_default($4,[m4_ifval($2,[AX_APPEND_FLAG([$2], [$1])])]) ;;
  89. *) m4_default($3,[AX_APPEND_FLAG([$VAR], [$1])]) ;;
  90. esac
  91. AS_VAR_POPDEF([VAR])dnl
  92. ])dnl AX_FLAGS_WARN_ALL
  93. dnl implementation tactics:
  94. dnl the for-argument contains a list of options. The first part of
  95. dnl these does only exist to detect the compiler - usually it is
  96. dnl a global option to enable -ansi or -extrawarnings. All other
  97. dnl compilers will fail about it. That was needed since a lot of
  98. dnl compilers will give false positives for some option-syntax
  99. dnl like -Woption or -Xoption as they think of it is a pass-through
  100. dnl to later compile stages or something. The "%" is used as a
  101. dnl delimiter. A non-option comment can be given after "%%" marks
  102. dnl which will be shown but not added to the respective C/CXXFLAGS.
  103. AC_DEFUN([AX_CFLAGS_WARN_ALL],[dnl
  104. AC_LANG_PUSH([C])
  105. AX_FLAGS_WARN_ALL([$1], [$2], [$3], [$4])
  106. AC_LANG_POP([C])
  107. ])
  108. AC_DEFUN([AX_CXXFLAGS_WARN_ALL],[dnl
  109. AC_LANG_PUSH([C++])
  110. AX_FLAGS_WARN_ALL([$1], [$2], [$3], [$4])
  111. AC_LANG_POP([C++])
  112. ])
  113. AC_DEFUN([AX_FCFLAGS_WARN_ALL],[dnl
  114. AC_LANG_PUSH([Fortran])
  115. AX_FLAGS_WARN_ALL([$1], [$2], [$3], [$4])
  116. AC_LANG_POP([Fortran])
  117. ])