You can not select more than 25 topics Topics must start with a letter or number, can include dashes ('-') and can be up to 35 characters long.
 
 
 
 
 
 

92 lines
3.0 KiB

  1. # progtest.m4 serial 7 (gettext-0.18.2)
  2. dnl Copyright (C) 1996-2003, 2005, 2008-2016 Free Software Foundation, Inc.
  3. dnl This file is free software; the Free Software Foundation
  4. dnl gives unlimited permission to copy and/or distribute it,
  5. dnl with or without modifications, as long as this notice is preserved.
  6. dnl
  7. dnl This file can be used in projects which are not available under
  8. dnl the GNU General Public License or the GNU Library General Public
  9. dnl License but which still want to provide support for the GNU gettext
  10. dnl functionality.
  11. dnl Please note that the actual code of the GNU gettext library is covered
  12. dnl by the GNU Library General Public License, and the rest of the GNU
  13. dnl gettext package is covered by the GNU General Public License.
  14. dnl They are *not* in the public domain.
  15. dnl Authors:
  16. dnl Ulrich Drepper <drepper@cygnus.com>, 1996.
  17. AC_PREREQ([2.50])
  18. # Search path for a program which passes the given test.
  19. dnl AM_PATH_PROG_WITH_TEST(VARIABLE, PROG-TO-CHECK-FOR,
  20. dnl TEST-PERFORMED-ON-FOUND_PROGRAM [, VALUE-IF-NOT-FOUND [, PATH]])
  21. AC_DEFUN([AM_PATH_PROG_WITH_TEST],
  22. [
  23. # Prepare PATH_SEPARATOR.
  24. # The user is always right.
  25. if test "${PATH_SEPARATOR+set}" != set; then
  26. # Determine PATH_SEPARATOR by trying to find /bin/sh in a PATH which
  27. # contains only /bin. Note that ksh looks also at the FPATH variable,
  28. # so we have to set that as well for the test.
  29. PATH_SEPARATOR=:
  30. (PATH='/bin;/bin'; FPATH=$PATH; sh -c :) >/dev/null 2>&1 \
  31. && { (PATH='/bin:/bin'; FPATH=$PATH; sh -c :) >/dev/null 2>&1 \
  32. || PATH_SEPARATOR=';'
  33. }
  34. fi
  35. # Find out how to test for executable files. Don't use a zero-byte file,
  36. # as systems may use methods other than mode bits to determine executability.
  37. cat >conf$$.file <<_ASEOF
  38. #! /bin/sh
  39. exit 0
  40. _ASEOF
  41. chmod +x conf$$.file
  42. if test -x conf$$.file >/dev/null 2>&1; then
  43. ac_executable_p="test -x"
  44. else
  45. ac_executable_p="test -f"
  46. fi
  47. rm -f conf$$.file
  48. # Extract the first word of "$2", so it can be a program name with args.
  49. set dummy $2; ac_word=[$]2
  50. AC_MSG_CHECKING([for $ac_word])
  51. AC_CACHE_VAL([ac_cv_path_$1],
  52. [case "[$]$1" in
  53. [[\\/]]* | ?:[[\\/]]*)
  54. ac_cv_path_$1="[$]$1" # Let the user override the test with a path.
  55. ;;
  56. *)
  57. ac_save_IFS="$IFS"; IFS=$PATH_SEPARATOR
  58. for ac_dir in ifelse([$5], , $PATH, [$5]); do
  59. IFS="$ac_save_IFS"
  60. test -z "$ac_dir" && ac_dir=.
  61. for ac_exec_ext in '' $ac_executable_extensions; do
  62. if $ac_executable_p "$ac_dir/$ac_word$ac_exec_ext"; then
  63. echo "$as_me: trying $ac_dir/$ac_word..." >&AS_MESSAGE_LOG_FD
  64. if [$3]; then
  65. ac_cv_path_$1="$ac_dir/$ac_word$ac_exec_ext"
  66. break 2
  67. fi
  68. fi
  69. done
  70. done
  71. IFS="$ac_save_IFS"
  72. dnl If no 4th arg is given, leave the cache variable unset,
  73. dnl so AC_PATH_PROGS will keep looking.
  74. ifelse([$4], , , [ test -z "[$]ac_cv_path_$1" && ac_cv_path_$1="$4"
  75. ])dnl
  76. ;;
  77. esac])dnl
  78. $1="$ac_cv_path_$1"
  79. if test ifelse([$4], , [-n "[$]$1"], ["[$]$1" != "$4"]); then
  80. AC_MSG_RESULT([$][$1])
  81. else
  82. AC_MSG_RESULT([no])
  83. fi
  84. AC_SUBST([$1])dnl
  85. ])