You can not select more than 25 topics Topics must start with a letter or number, can include dashes ('-') and can be up to 35 characters long.
 
 
 
 
 
 

207 lines
6.2 KiB

  1. ad
  2. dnl Process this file with autoconf to produce a configure script.
  3. dnl The ONLY thing this is used for is to configure for different
  4. dnl linux architectures and configurations, it is not used to make the
  5. dnl code more portable
  6. dnl You MUST have an environment that has all the POSIX functions and
  7. dnl some of the more populare bsd/sysv ones (like select). You'll also
  8. dnl need a C++ compiler that is semi-standard conformant, exceptions are
  9. dnl not used but STL is.
  10. dnl 'make -f Makefile startup' will generate the configure file from
  11. dnl configure.in correctly and can be run at any time
  12. AC_PREREQ(2.50)
  13. AC_INIT(configure.in)
  14. AC_CONFIG_AUX_DIR(buildlib)
  15. AC_CONFIG_HEADER(include/config.h:buildlib/config.h.in include/apti18n.h:buildlib/apti18n.h.in)
  16. dnl -- SET THIS TO THE RELEASE VERSION --
  17. AC_DEFINE_UNQUOTED(VERSION,"0.6.40.2")
  18. PACKAGE="apt"
  19. AC_DEFINE_UNQUOTED(PACKAGE,"$PACKAGE")
  20. AC_SUBST(PACKAGE)
  21. dnl Check the archs, we want the target type.
  22. AC_CANONICAL_SYSTEM
  23. dnl Check our C compiler
  24. AC_CHECK_TOOL_PREFIX
  25. AC_PROG_CC
  26. AC_ISC_POSIX
  27. dnl Check for other programs
  28. AC_PROG_CXX
  29. AC_PROG_CPP
  30. AC_PROG_RANLIB
  31. AC_CHECK_TOOL(AR,ar,"ar")
  32. dnl Checks for sockets
  33. SAVE_LIBS="$LIBS"
  34. LIBS=""
  35. AC_SEARCH_LIBS(gethostbyname,nsl)
  36. AC_SEARCH_LIBS(connect,socket)
  37. SOCKETLIBS="$LIBS"
  38. AC_SUBST(SOCKETLIBS)
  39. LIBS="$SAVE_LIBS"
  40. dnl Checks for pthread -- disabled due to glibc bugs jgg
  41. dnl AC_CHECK_LIB(pthread, pthread_create,[AC_DEFINE(HAVE_PTHREAD) PTHREADLIB="-lpthread"])
  42. AC_SUBST(PTHREADLIB)
  43. dnl if test "$PTHREADLIB" != "-lpthread"; then
  44. dnl AC_MSG_ERROR(failed: I need posix threads, pthread)
  45. dnl fi
  46. dnl Check for BDB
  47. saveLIBS="$LIBS"
  48. LIBS="$LIBS -ldb"
  49. AC_CHECK_HEADER(db.h,
  50. [AC_MSG_CHECKING(if we can link against BerkeleyDB)
  51. AC_LINK_IFELSE(
  52. [AC_LANG_PROGRAM(
  53. [#include <db.h>],
  54. [int r, s, t; db_version(&r, &s, &t);]
  55. )],
  56. [AC_DEFINE(HAVE_BDB)
  57. BDBLIB="-ldb"
  58. AC_MSG_RESULT(yes)],
  59. [BDBLIB=""
  60. AC_MSG_RESULT(no)]
  61. )]
  62. )
  63. LIBS="$saveLIBS"
  64. AC_SUBST(BDBLIB)
  65. dnl Converts the ARCH to be something singular for this general CPU family
  66. dnl This is often the dpkg architecture string.
  67. AC_MSG_CHECKING(system architecture)
  68. archset="`awk \" ! /^#|^\\\$/ { if(match(\\\"$target_cpu\\\",\\\"^\\\"\\\$1\\\"\\\$\\\")) {print \\\$2; exit}}\" $srcdir/buildlib/archtable`"
  69. if test "x$archset" = "x"; then
  70. AC_MSG_ERROR(failed: use --host= or check buildlib/archtable)
  71. fi
  72. AC_MSG_RESULT($archset)
  73. AC_DEFINE_UNQUOTED(COMMON_CPU,"$archset")
  74. dnl Get a common name for the host OS - this is primarily only for HURD and is
  75. dnl non fatal if it fails
  76. AC_MSG_CHECKING(system OS)
  77. osset="`awk \" ! /^#|^\\\$/ {if (match(\\\"$target_vendor-$target_os\\\",\\\$1)) {print \\\$2; exit}}\" $srcdir/buildlib/ostable`"
  78. AC_MSG_RESULT($osset)
  79. AC_DEFINE_UNQUOTED(COMMON_OS,"$osset")
  80. dnl We use C99 types if at all possible
  81. AC_CACHE_CHECK([for C99 integer types],c9x_ints,[
  82. AC_TRY_COMPILE([#include <inttypes.h>],
  83. [uint8_t Foo1;uint16_t Foo2;uint32_t Foo3;],
  84. c9x_ints=yes,c9x_ints=no)])
  85. dnl Single Unix Spec statvfs
  86. AC_CHECK_FUNC(statvfs,[HAVE_STATVFS=yes])
  87. AC_SUBST(HAVE_STATVFS)
  88. dnl Arg, linux and bsd put their statfs function in different places
  89. if test x"$HAVE_STATVFS" != x"yes"; then
  90. AC_EGREP_HEADER(statfs,sys/vfs.h,[AC_DEFINE(HAVE_VFS_H)],[
  91. AC_EGREP_HEADER(statfs,sys/mount.h,[AC_DEFINE(HAVE_MOUNT_H)],[AC_MSG_ERROR(failed: Need statvfs)])
  92. ])
  93. fi
  94. dnl We should use the real timegm function if we have it.
  95. AC_CHECK_FUNC(timegm,AC_DEFINE(HAVE_TIMEGM))
  96. AC_SUBST(HAVE_TIMEGM)
  97. dnl Check the sizes etc. of the architecture
  98. dnl This is stupid, it should just use the AC macros like it does below
  99. dnl Cross compilers can either get a real C library or preload the cache
  100. dnl with their size values.
  101. changequote(,)
  102. archline="`awk \" ! /^#|^\\\$/ {if (match(\\\"$archset\\\",\\\$1)) {print; exit}}\" $srcdir/buildlib/sizetable | cut -f 2- -d ' '`"
  103. if test "x$archline" != "x"; then
  104. changequote([,])
  105. set $archline
  106. if test "$1" = "little"; then
  107. ac_cv_c_bigendian=no
  108. else
  109. ac_cv_c_bigendian=yes
  110. fi
  111. size_char=$2
  112. size_int=$3
  113. size_short=$4
  114. size_long=$5
  115. fi
  116. dnl I wonder what AC_C_BIGENDIAN does if you cross compile...
  117. dnl This is probably bogus, as above we only care if we have to build our own
  118. dnl C9x types.
  119. if test "$cross_compiling" = "yes" -a "x$archline" = "x"; then
  120. AC_MSG_ERROR(When cross compiling, architecture must be present in sizetable)
  121. fi
  122. AC_C_BIGENDIAN
  123. dnl We do not need this if we have inttypes!
  124. HAVE_C9X=yes
  125. if test x"$c9x_ints" = x"no"; then
  126. AC_CHECK_SIZEOF(char,$size_char)
  127. AC_CHECK_SIZEOF(int,$size_int)
  128. AC_CHECK_SIZEOF(short,$size_short)
  129. AC_CHECK_SIZEOF(long,$size_long)
  130. HAVE_C9X=
  131. AC_SUBST(HAVE_C9X)
  132. fi
  133. dnl HP-UX sux..
  134. AC_MSG_CHECKING(for missing socklen_t)
  135. AC_EGREP_HEADER(socklen_t, sys/socket.h,[AC_MSG_RESULT(no)],[
  136. AC_DEFINE(NEED_SOCKLEN_T_DEFINE)
  137. NEED_SOCKLEN_T_DEFINE=yes
  138. AC_MSG_RESULT(missing.)])
  139. AC_SUBST(NEED_SOCKLEN_T_DEFINE)
  140. dnl HP-UX needs -d_XOPEN_SOURCE_EXTENDED for h_errno
  141. AC_MSG_CHECKING(for h_errno)
  142. AC_EGREP_HEADER(h_errno, netdb.h, [AC_MSG_RESULT(normal)],
  143. [CPPFLAGS="$CPPFLAGS -D_XOPEN_SOURCE_EXTENDED"
  144. AC_EGREP_HEADER(h_errno, netdb.h,
  145. [AC_MSG_RESULT(needs _XOPEN_SOURCE_EXTENDED)],
  146. [AC_MSG_ERROR("not found.")])
  147. ])
  148. dnl Check for debiandoc
  149. AC_PATH_PROG(DEBIANDOC_HTML,debiandoc2html)
  150. AC_PATH_PROG(DEBIANDOC_TEXT,debiandoc2text)
  151. dnl Check for the SGML tools needed to build man pages
  152. AC_PATH_PROG(DOCBOOK2MAN,docbook2man)
  153. dnl Check for the XML tools needed to build man pages
  154. AC_PATH_PROG(XMLTO,xmlto)
  155. dnl Check for the XML tools needed to build man pages
  156. AC_PATH_PROG(XMLTO,xmlto)
  157. dnl Check for YODL
  158. dnl AC_CHECK_PROG(YODL_MAN,yodl2man,"yes","")
  159. ah_NUM_PROCS
  160. rc_GLIBC_VER
  161. rc_LIBSTDCPP_VER
  162. ah_GCC3DEP
  163. dnl It used to be that the user could select translations and that could get
  164. dnl passed to the makefiles, but now that can only work if you use special
  165. dnl gettext approved makefiles, so this feature is unsupported by this.
  166. ALL_LINGUAS="da de en_GB es fr hu it nl no_NO pl pt_BR ru sv zh_TW"
  167. AM_GNU_GETTEXT(external)
  168. if test x"$USE_NLS" = "xyes"; then
  169. AC_DEFINE(USE_NLS)
  170. fi
  171. AC_SUBST(USE_NLS)
  172. AC_PATH_PROG(BASH, bash)
  173. AC_OUTPUT(environment.mak:buildlib/environment.mak.in makefile:buildlib/makefile.in,make -s dirs)