You can not select more than 25 topics Topics must start with a letter or number, can include dashes ('-') and can be up to 35 characters long.
 
 
 
 
 
 

218 lines
6.5 KiB

  1. ad
  2. dnl Process this file with autoconf to produce a configure script.
  3. dnl The ONLY thing this is used for is to configure for different
  4. dnl linux architectures and configurations, it is not used to make the
  5. dnl code more portable
  6. dnl You MUST have an environment that has all the POSIX functions and
  7. dnl some of the more populare bsd/sysv ones (like select). You'll also
  8. dnl need a C++ compiler that is semi-standard conformant, exceptions are
  9. dnl not used but STL is.
  10. dnl 'make -f Makefile startup' will generate the configure file from
  11. dnl configure.in correctly and can be run at any time
  12. AC_PREREQ(2.50)
  13. AC_INIT(configure.in)
  14. AC_CONFIG_AUX_DIR(buildlib)
  15. AC_CONFIG_HEADER(include/config.h:buildlib/config.h.in include/apti18n.h:buildlib/apti18n.h.in)
  16. dnl -- SET THIS TO THE RELEASE VERSION --
  17. AC_DEFINE_UNQUOTED(VERSION,"0.7.26~exp6")
  18. PACKAGE="apt"
  19. AC_DEFINE_UNQUOTED(PACKAGE,"$PACKAGE")
  20. AC_SUBST(PACKAGE)
  21. dnl Check the archs, we want the target type.
  22. AC_CANONICAL_SYSTEM
  23. dnl Check our C compiler
  24. AC_CHECK_TOOL_PREFIX
  25. AC_PROG_CC
  26. AC_ISC_POSIX
  27. dnl Check for other programs
  28. AC_PROG_CXX
  29. AC_PROG_CPP
  30. AC_PROG_RANLIB
  31. AC_CHECK_TOOL(AR,ar,"ar")
  32. dnl Checks for sockets
  33. SAVE_LIBS="$LIBS"
  34. LIBS=""
  35. AC_SEARCH_LIBS(gethostbyname,nsl)
  36. AC_SEARCH_LIBS(connect,socket)
  37. SOCKETLIBS="$LIBS"
  38. AC_SUBST(SOCKETLIBS)
  39. LIBS="$SAVE_LIBS"
  40. dnl Checks for pthread -- disabled due to glibc bugs jgg
  41. dnl AC_CHECK_LIB(pthread, pthread_create,[AC_DEFINE(HAVE_PTHREAD) PTHREADLIB="-lpthread"])
  42. AC_SUBST(PTHREADLIB)
  43. dnl if test "$PTHREADLIB" != "-lpthread"; then
  44. dnl AC_MSG_ERROR(failed: I need posix threads, pthread)
  45. dnl fi
  46. dnl Check for BDB
  47. saveLIBS="$LIBS"
  48. LIBS="$LIBS -ldb"
  49. AC_CHECK_HEADER(db.h,
  50. [AC_MSG_CHECKING(if we can link against BerkeleyDB)
  51. AC_LINK_IFELSE(
  52. [AC_LANG_PROGRAM(
  53. [#include <db.h>],
  54. [int r, s, t; db_version(&r, &s, &t);]
  55. )],
  56. [AC_DEFINE(HAVE_BDB)
  57. BDBLIB="-ldb"
  58. AC_MSG_RESULT(yes)],
  59. [BDBLIB=""
  60. AC_MSG_RESULT(no)]
  61. )]
  62. )
  63. LIBS="$saveLIBS"
  64. AC_CHECK_LIB(curl, curl_easy_init,
  65. [AC_CHECK_HEADER(curl/curl.h,
  66. curl_ok=yes,
  67. curl_ok=no)],
  68. AC_MSG_ERROR([failed: I need CURL due https support]),
  69. )
  70. AC_SUBST(BDBLIB)
  71. AC_CHECK_LIB(z, gzopen,
  72. [AC_CHECK_HEADER(zlib.h, [], AC_MSG_ERROR([failed: zlib.h not found]))],
  73. AC_MSG_ERROR([failed: Need libz]))
  74. dnl Converts the ARCH to be something singular for this general CPU family
  75. dnl This is often the dpkg architecture string.
  76. dnl First check against the full canonical canoncial-system-type in $target
  77. dnl and if that fails, just look for the cpu
  78. AC_MSG_CHECKING(debian architecture)
  79. archset="`dpkg-architecture -qDEB_HOST_ARCH`"
  80. if test "x$archset" = "x"; then
  81. AC_MSG_ERROR([failed: use --host= or output from dpkg-architecture])
  82. fi
  83. AC_MSG_RESULT($archset)
  84. AC_DEFINE_UNQUOTED(COMMON_ARCH,"$archset")
  85. dnl We use C99 types if at all possible
  86. AC_CACHE_CHECK([for C99 integer types],apt_cv_c9x_ints,[
  87. AC_TRY_COMPILE([#include <inttypes.h>],
  88. [uint8_t Foo1;uint16_t Foo2;uint32_t Foo3;],
  89. apt_cv_c9x_ints=yes,apt_cv_c9x_ints=no)])
  90. dnl Single Unix Spec statvfs
  91. AC_CHECK_FUNC(statvfs,[HAVE_STATVFS=yes])
  92. AC_SUBST(HAVE_STATVFS)
  93. dnl Arg, linux and bsd put their statfs function in different places
  94. if test x"$HAVE_STATVFS" != x"yes"; then
  95. AC_EGREP_HEADER(statfs,sys/vfs.h,[AC_DEFINE(HAVE_VFS_H)],[
  96. AC_EGREP_HEADER(statfs,sys/mount.h,[AC_DEFINE(HAVE_MOUNT_H)],[AC_MSG_ERROR(failed: Need statvfs)])
  97. ])
  98. fi
  99. AC_CHECK_MEMBERS([struct statfs.f_type],,,
  100. [$ac_includes_default
  101. #include <sys/vfs.h>])
  102. dnl We should use the real timegm function if we have it.
  103. AC_CHECK_FUNC(timegm,AC_DEFINE(HAVE_TIMEGM))
  104. AC_SUBST(HAVE_TIMEGM)
  105. dnl Check the sizes etc. of the architecture
  106. dnl This is stupid, it should just use the AC macros like it does below
  107. dnl Cross compilers can either get a real C library or preload the cache
  108. dnl with their size values.
  109. changequote(,)
  110. archline="`awk \" ! /^#|^\\\$/ {if (match(\\\"$archset\\\",\\\$1)) {print; exit}}\" $srcdir/buildlib/sizetable | cut -f 2- -d ' '`"
  111. if test "x$archline" != "x"; then
  112. changequote([,])
  113. set $archline
  114. if test "$1" = "little"; then
  115. ac_cv_c_bigendian=no
  116. else
  117. ac_cv_c_bigendian=yes
  118. fi
  119. size_char=$2
  120. size_int=$3
  121. size_short=$4
  122. size_long=$5
  123. fi
  124. dnl I wonder what AC_C_BIGENDIAN does if you cross compile...
  125. dnl This is probably bogus, as above we only care if we have to build our own
  126. dnl C9x types.
  127. if test "$cross_compiling" = "yes" -a "x$archline" = "x"; then
  128. AC_MSG_ERROR(When cross compiling, architecture must be present in sizetable)
  129. fi
  130. AC_C_BIGENDIAN
  131. dnl We do not need this if we have inttypes!
  132. HAVE_C9X=yes
  133. if test x"$apt_cv_c9x_ints" = x"no"; then
  134. AC_CHECK_SIZEOF(char,$size_char)
  135. AC_CHECK_SIZEOF(int,$size_int)
  136. AC_CHECK_SIZEOF(short,$size_short)
  137. AC_CHECK_SIZEOF(long,$size_long)
  138. HAVE_C9X=
  139. AC_SUBST(HAVE_C9X)
  140. fi
  141. dnl HP-UX sux..
  142. AC_MSG_CHECKING(for missing socklen_t)
  143. AC_EGREP_HEADER(socklen_t, sys/socket.h,[AC_MSG_RESULT(no)],[
  144. AC_DEFINE(NEED_SOCKLEN_T_DEFINE)
  145. NEED_SOCKLEN_T_DEFINE=yes
  146. AC_MSG_RESULT(missing.)])
  147. AC_SUBST(NEED_SOCKLEN_T_DEFINE)
  148. dnl HP-UX needs -d_XOPEN_SOURCE_EXTENDED for h_errno
  149. AC_MSG_CHECKING(for h_errno)
  150. AC_EGREP_HEADER(h_errno, netdb.h, [AC_MSG_RESULT(normal)],
  151. [CPPFLAGS="$CPPFLAGS -D_XOPEN_SOURCE_EXTENDED"
  152. AC_EGREP_HEADER(h_errno, netdb.h,
  153. [AC_MSG_RESULT(needs _XOPEN_SOURCE_EXTENDED)],
  154. [AC_MSG_ERROR("not found.")])
  155. ])
  156. dnl Check for debiandoc
  157. AC_PATH_PROG(DEBIANDOC_HTML,debiandoc2html)
  158. AC_PATH_PROG(DEBIANDOC_TEXT,debiandoc2text)
  159. dnl Check for doxygen
  160. AC_PATH_PROG(DOXYGEN, doxygen)
  161. dnl Check for the XSLTProc tool needed to build man pages together with po4a
  162. AC_PATH_PROG(XSLTPROC,xsltproc)
  163. dnl Check for the po4a tool needed to build man pages
  164. AC_PATH_PROG(PO4A,po4a)
  165. dnl Check for graphviz
  166. AC_CHECK_PROG([HAVE_DOT], [dot], [YES], [NO])
  167. AC_PATH_PROG([DOT], [dot], [])
  168. DOTDIR=$(dirname $DOT)
  169. AC_SUBST(DOTDIR)
  170. ah_NUM_PROCS
  171. ah_GCC3DEP
  172. dnl It used to be that the user could select translations and that could get
  173. dnl passed to the makefiles, but now that can only work if you use special
  174. dnl gettext approved makefiles, so this feature is unsupported by this.
  175. ALL_LINGUAS="bg bs ca cs cy da de dz el en_GB es eu fi fr gl hu it ja ko ku nb nl nn pl pt_BR pt ro ru sk sl sv th tl uk vi zn_CN zh_TW"
  176. AM_GNU_GETTEXT(external)
  177. if test x"$USE_NLS" = "xyes"; then
  178. AC_DEFINE(USE_NLS)
  179. fi
  180. AC_SUBST(USE_NLS)
  181. AC_PATH_PROG(BASH, bash)
  182. AC_OUTPUT(environment.mak:buildlib/environment.mak.in makefile:buildlib/makefile.in doc/Doxyfile,make -s dirs)