You can not select more than 25 topics Topics must start with a letter or number, can include dashes ('-') and can be up to 35 characters long.
 
 
 
 
 

280 lines
9.1 KiB

  1. dnl
  2. dnl Copyright (c) 2004 - 2008 The Xfce development team
  3. dnl
  4. dnl 2005-2007 Jasper Huijsmans <jasper@xfce.org>
  5. dnl 2006-2008 Nick Schermer <nick@xfce.org>
  6. dnl
  7. dnl ***************************
  8. dnl *** Version information ***
  9. dnl ***************************
  10. m4_define([libxfce4panel_verinfo], [3:0:0]) dnl current:revision:age
  11. m4_define([libxfce4panel_version_api], [1.0])
  12. m4_define([xfce4_panel_version_major], [4])
  13. m4_define([xfce4_panel_version_minor], [7])
  14. m4_define([xfce4_panel_version_micro], [7])
  15. m4_define([xfce4_panel_version_nano], []) dnl leave this empty to have no nano version
  16. m4_define([xfce4_panel_version_build], [@REVISION@])
  17. m4_define([xfce4_panel_version_tag], [])
  18. m4_define([xfce4_panel_version], [xfce4_panel_version_major().xfce4_panel_version_minor().xfce4_panel_version_micro()ifelse(xfce4_panel_version_nano(), [], [], [.xfce4_panel_version_nano()])ifelse(xfce4_panel_version_tag(), [git], [xfce4_panel_version_tag()-xfce4_panel_version_build()], [xfce4_panel_version_tag()])])
  19. dnl *******************************************
  20. dnl *** Debugging support for GIT snapshots ***
  21. dnl *******************************************
  22. m4_define([panel_debug_default], [ifelse(xfce4_panel_version_tag(), [git], [yes], [minimum])])
  23. dnl ***************************
  24. dnl *** Initialize autoconf ***
  25. dnl ***************************
  26. AC_COPYRIGHT([Copyright (c) 2002 - 2011
  27. The Xfce development team. All rights reserved.
  28. Written for Xfce by Jasper Huijsmans <jasper@xfce.org>
  29. and Nick Schermer <nick@xfce.org>.])
  30. AC_INIT([xfce4-panel], [xfce4_panel_version], [http://bugzilla.xfce.org/], [xfce4-panel])
  31. AC_PREREQ([2.50])
  32. AC_REVISION([xfce4_panel_version_build])
  33. dnl ***************************
  34. dnl *** Initialize automake ***
  35. dnl ***************************
  36. AM_CONFIG_HEADER([config.h])
  37. AM_INIT_AUTOMAKE([1.8 no-dist-gzip dist-bzip2 tar-ustar])
  38. AM_MAINTAINER_MODE()
  39. m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  40. dnl *******************************
  41. dnl *** Check for UNIX variants ***
  42. dnl *******************************
  43. AC_AIX()
  44. AC_ISC_POSIX()
  45. dnl ********************************
  46. dnl *** Check for basic programs ***
  47. dnl ********************************
  48. AC_PROG_CC()
  49. AM_PROG_CC_C_O()
  50. AC_PROG_LD()
  51. AC_PROG_INSTALL()
  52. AC_PROG_INTLTOOL()
  53. AC_PROG_LIBTOOL()
  54. dnl **************************
  55. dnl *** Initialize libtool ***
  56. dnl **************************
  57. AC_DISABLE_STATIC()
  58. AC_PROG_LIBTOOL()
  59. AC_CHECK_PROGS([PERL], [perl5 perl])
  60. dnl **************************************
  61. dnl *** Substitute version information ***
  62. dnl **************************************
  63. LIBXFCE4PANEL_VERINFO=libxfce4panel_verinfo()
  64. AC_SUBST([LIBXFCE4PANEL_VERINFO])
  65. dnl **************************
  66. dnl *** Substitute version ***
  67. dnl **************************
  68. LIBXFCE4PANEL_VERSION=xfce4_panel_version()
  69. LIBXFCE4PANEL_VERSION_API=libxfce4panel_version_api()
  70. LIBXFCE4PANEL_VERSION_MAJOR=xfce4_panel_version_major()
  71. LIBXFCE4PANEL_VERSION_MINOR=xfce4_panel_version_minor()
  72. LIBXFCE4PANEL_VERSION_MICRO=xfce4_panel_version_micro()
  73. AC_SUBST([LIBXFCE4PANEL_VERSION])
  74. AC_SUBST([LIBXFCE4PANEL_VERSION_API])
  75. AC_SUBST([LIBXFCE4PANEL_VERSION_MAJOR])
  76. AC_SUBST([LIBXFCE4PANEL_VERSION_MINOR])
  77. AC_SUBST([LIBXFCE4PANEL_VERSION_MICRO])
  78. dnl **********************************
  79. dnl *** Check for standard headers ***
  80. dnl **********************************
  81. AC_HEADER_STDC()
  82. AC_CHECK_HEADERS([stdlib.h unistd.h locale.h stdio.h errno.h time.h string.h \
  83. math.h sys/types.h sys/wait.h memory.h signal.h sys/prctl.h \
  84. libintl.h])
  85. AC_CHECK_FUNCS([bind_textdomain_codeset])
  86. dnl ******************************
  87. dnl *** Check for i18n support ***
  88. dnl ******************************
  89. XDT_I18N([@LINGUAS@])
  90. dnl *******************************
  91. dnl *** Check for X11 installed ***
  92. dnl *******************************
  93. XDT_CHECK_LIBX11_REQUIRE()
  94. dnl ***********************************
  95. dnl *** Check for required packages ***
  96. dnl ***********************************
  97. XDT_CHECK_PACKAGE([LIBXFCE4UTIL], [libxfce4util-1.0], [4.6.0])
  98. XDT_CHECK_PACKAGE([GARCON], [garcon-1], [0.1.4])
  99. XDT_CHECK_PACKAGE([LIBXFCE4UI], [libxfce4ui-1], [4.7.1])
  100. XDT_CHECK_PACKAGE([XFCONF], [libxfconf-0], [4.7.2])
  101. XDT_CHECK_PACKAGE([EXO], [exo-1], [0.5.1])
  102. XDT_CHECK_PACKAGE([GTK], [gtk+-2.0], [2.14.0])
  103. XDT_CHECK_PACKAGE([GLIB], [glib-2.0], [2.18.0])
  104. XDT_CHECK_PACKAGE([GIO], [gio-2.0], [2.18.0])
  105. XDT_CHECK_PACKAGE([GMODULE], [gmodule-2.0], [2.18.0])
  106. XDT_CHECK_PACKAGE([DBUS], [dbus-glib-1], [0.73])
  107. XDT_CHECK_PACKAGE([CAIRO], [cairo], [1.0.0])
  108. XDT_CHECK_PACKAGE([LIBWNCK], [libwnck-1.0], [2.22])
  109. dnl **********************************
  110. dnl *** Optional GIO UNIX features ***
  111. dnl **********************************
  112. XDT_CHECK_OPTIONAL_PACKAGE([GIO_UNIX], [gio-unix-2.0],
  113. [2.18.0], [gio-unix], [GIO UNIX features])
  114. dnl ***************************************************
  115. dnl *** Check if we need to build the documentation ***
  116. dnl ***************************************************
  117. AC_ARG_ENABLE([gen-doc], [AC_HELP_STRING([--enable-gen-doc],
  118. [Generate HTML documentation (requires gnome-doc-utils) [default=no]])],,
  119. [enable_gen_doc=no])
  120. if test x"$enable_gen_doc" = x"yes"; then
  121. XDT_CHECK_PACKAGE([GNOME_DOC_UTILS], [gnome-doc-utils], [0.19.2],
  122. [
  123. AC_PATH_PROG([XML2PO], [xml2po], [no])
  124. if test x"$XML2PO" = x"no"; then
  125. enable_gen_doc=no
  126. fi
  127. AC_PATH_PROG([GNOME_DOC_TOOL], [gnome-doc-tool], [no])
  128. if test x"$GNOME_DOC_TOOL" = x"no"; then
  129. enable_gen_doc=no
  130. fi
  131. ],
  132. [
  133. enable_gen_doc=no
  134. ])
  135. if test x"$enable_gen_doc" = x"no"; then
  136. AC_MSG_ERROR([Compiling with --enable-gen-doc but no suitable gnome-doc-utils found.])
  137. fi
  138. fi
  139. AM_CONDITIONAL([GENERATE_DOCUMENTATION], [test x"$enable_gen_doc" = x"yes"])
  140. dnl *************************
  141. dnl *** Check for gtk-doc ***
  142. dnl *************************
  143. GTK_DOC_CHECK([1.9])
  144. dnl ***********************************
  145. dnl *** Check for debugging support ***
  146. dnl ***********************************
  147. XDT_FEATURE_DEBUG([panel_debug_default])
  148. dnl **************************************
  149. dnl *** Check for linker optimizations ***
  150. dnl **************************************
  151. XDT_FEATURE_LINKER_OPTS()
  152. dnl ****************************************
  153. dnl *** Check for ELF visibility support ***
  154. dnl ****************************************
  155. AC_ARG_ENABLE([visibility], AC_HELP_STRING([--disable-visibility], [Do not use ELF visibility attributes]), [], [enable_visibility=yes])
  156. have_gnuc_visibility=no
  157. if test x"$enable_visibility" != x"no"; then
  158. dnl Check whether the compiler supports the visibility attribute
  159. save_CFLAGS="$CFLAGS"
  160. CFLAGS="$CFLAGS -Wall -Werror"
  161. AC_MSG_CHECKING([whether $CC supports the GNUC visibility attribute])
  162. AC_COMPILE_IFELSE(AC_LANG_SOURCE(
  163. [
  164. void test_default (void);
  165. void test_hidden (void);
  166. void __attribute__ ((visibility("default"))) test_default (void) {}
  167. void __attribute__ ((visibility("hidden"))) test_hidden (void) {}
  168. int main (int argc, char **argv) { test_default (); test_hidden (); return 0; }
  169. ]),
  170. [
  171. have_gnuc_visibility=yes
  172. AC_MSG_RESULT([yes])
  173. ],
  174. [
  175. AC_MSG_RESULT([no])
  176. ])
  177. CFLAGS="$save_CFLAGS"
  178. fi
  179. if test x"$have_gnuc_visibility" = x"yes"; then
  180. CPPFLAGS="$CPPFLAGS -DHAVE_GNUC_VISIBILITY"
  181. fi
  182. AM_CONDITIONAL([HAVE_GNUC_VISIBILITY], [test x"$have_gnuc_visibility" = x"yes"])
  183. dnl *************************************
  184. dnl *** Compensate for broken gtk-doc ***
  185. dnl *************************************
  186. XDT_SUPPORTED_FLAGS([GTK_DOC_EXTRA_CFLAGS], [-Wno-sign-compare])
  187. AC_SUBST([GTK_DOC_EXTRA_CFLAGS])
  188. dnl *********************************
  189. dnl *** Substitute platform flags ***
  190. dnl *********************************
  191. AC_MSG_CHECKING([PLATFORM_CPPFLAGS])
  192. AC_MSG_RESULT([$PLATFORM_CPPFLAGS])
  193. AC_SUBST([PLATFORM_CPPFLAGS])
  194. AC_MSG_CHECKING([PLATFORM_CFLAGS])
  195. AC_MSG_RESULT([$PLATFORM_CFLAGS])
  196. AC_SUBST([PLATFORM_CFLAGS])
  197. AC_MSG_CHECKING([PLATFORM_LDFLAGS])
  198. AC_MSG_RESULT([$PLATFORM_LDFLAGS])
  199. AC_SUBST([PLATFORM_LDFLAGS])
  200. AC_OUTPUT([
  201. Makefile
  202. common/Makefile
  203. docs/Makefile
  204. docs/manual/Makefile
  205. docs/manual/figures/Makefile
  206. docs/manual/po/Makefile
  207. docs/references/Makefile
  208. docs/references/version.xml
  209. icons/Makefile
  210. icons/16x16/Makefile
  211. icons/22x22/Makefile
  212. icons/24x24/Makefile
  213. icons/32x32/Makefile
  214. icons/48x48/Makefile
  215. icons/scalable/Makefile
  216. libxfce4panel/Makefile
  217. libxfce4panel/libxfce4panel-1.0.pc
  218. libxfce4panel/libxfce4panel-config.h
  219. migrate/Makefile
  220. panel/Makefile
  221. wrapper/Makefile
  222. plugins/Makefile
  223. plugins/actions/Makefile
  224. plugins/applicationsmenu/Makefile
  225. plugins/clock/Makefile
  226. plugins/directorymenu/Makefile
  227. plugins/launcher/Makefile
  228. plugins/pager/Makefile
  229. plugins/separator/Makefile
  230. plugins/showdesktop/Makefile
  231. plugins/systray/Makefile
  232. plugins/tasklist/Makefile
  233. plugins/windowmenu/Makefile
  234. po/Makefile.in
  235. ])
  236. dnl ***************************
  237. dnl *** Print configuration ***
  238. dnl ***************************
  239. echo
  240. echo "Build Configuration:"
  241. echo
  242. echo "* Debug Support: $enable_debug"
  243. echo "* GNU Visibility: $have_gnuc_visibility"
  244. if test x"$enable_gen_doc" = x"yes"; then
  245. echo "* Documentation: yes (generate)"
  246. elif test -d "${srcdir}/docs/manual/html"; then
  247. echo "* Documentation: yes (in tarball)"
  248. else
  249. echo "* Documentation: no"
  250. fi
  251. echo